1 files changed, 37 insertions, 0 deletions
diff --git a/dev-python/zope-dottedname/zope-dottedname-5.0.ebuild b/dev-python/zope-dottedname/zope-dottedname-5.0.ebuild
new file mode 100644
index 0000000..8b6b75f
--- /dev/null
+++ b/dev-python/zope-dottedname/zope-dottedname-5.0.ebuild
@@ -0,0 +1,37 @@
+# Copyright 2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{9..11} )
+
+inherit distutils-r1
+
+DESCRIPTION="Resolve strings containing dotted names into the appropriate python object"
+HOMEPAGE="https://github.com/zopefoundation/zope.dottedname"
+SRC_URI="https://github.com/zopefoundation/zope.dottedname/archive/${PV}.tar.gz -> ${P}.gh.tar.gz"
+S="${WORKDIR}/${PN/-/\.}-${PV}"
+
+LICENSE="ZPL"
+SLOT="0"
+KEYWORDS="~amd64"
+
+distutils_enable_sphinx docs
+distutils_enable_tests unittest
+
+src_prepare() {
+	# strip rdep specific to namespaces
+	sed -i -e "/'setuptools'/d" setup.py || die
+	distutils-r1_src_prepare
+}
+
+python_compile() {
+	distutils-r1_python_compile
+	find "${BUILD_DIR}" -name '*.pth' -delete || die
+}
+
+src_test() {
+	cd "${S}/src/zope/dottedname" || die
+	distutils-r1_src_test
+}