1 files changed, 46 insertions, 0 deletions
diff --git a/app-portage/puppy/puppy-9999.ebuild b/app-portage/puppy/puppy-9999.ebuild
new file mode 100644
index 0000000..182b948
--- /dev/null
+++ b/app-portage/puppy/puppy-9999.ebuild
@@ -0,0 +1,46 @@
+# Copyright 2023-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{10..13} )
+
+inherit python-single-r1
+
+DESCRIPTION="Utility for compiling packages on remote hosts using Portage"
+HOMEPAGE="https://gitlab.com/doasu/puppy"
+
+if [[ ${PV} == 9999 ]]; then
+	# Use my fork for now
+	EGIT_REPO_URI="https://gitlab.com/MrRoy3/${PN}.git"
+	inherit git-r3
+else
+	SRC_URI="https://gitlab.com/doasu/${PN}/-/archive/${PV}/${P}.tar.bz2"
+	KEYWORDS="~amd64"
+fi
+
+LICENSE="GPL-3+"
+SLOT="0"
+IUSE="+client +server"
+REQUIRED_USE="
+	|| ( client server )
+	${PYTHON_REQUIRED_USE}
+"
+
+RDEPEND="
+	sys-apps/portage
+	${PYTHON_DEPS}
+"
+DEPEND="${RDEPEND}"
+
+src_install() {
+	python_domodule server_request.py
+
+	if use server; then
+		python_doscript portage_server.py
+	fi
+
+	if use client; then
+		python_doscript pup.py
+	fi
+}