3 files changed, 114 insertions, 0 deletions
diff --git a/net-voip/jami-daemon/Manifest b/net-voip/jami-daemon/Manifest
new file mode 100644
index 0000000..abdad3d
--- /dev/null
+++ b/net-voip/jami-daemon/Manifest
@@ -0,0 +1,2 @@
+DIST jami-daemon-0_pre20230113.tar.bz2 3256611 BLAKE2B a119286461d9f8fd04b46d15b55d3525a635941ad9ae79d979e311fdb00434ced840d80aaeb70a9ac7be4e5575138e59d8d56915439d054c3a22786fd44a7eee SHA512 ae325576589dd20e076d78ba915d4eaec6e7164f22929917a7b4d0cd2678f2957516bbf63f737e796a7e20fd287765e209eb0f7ce46c0b60954f1bf350360fff
+DIST pjproject-eae25732568e600d248aa8c226271ff6b81df170.tar.gz 9690408 BLAKE2B a0b8df3326ffbff201916ae57ec0930ec7c015687681e8f88790077a8d58a15133502a2045d22682a5f41768062c1cebcf2a6ac5ca007ebe5a11e44c55e95da2 SHA512 43e2e92079bbc749376f567649567238b57fb128c4202f7109cb050baf471c19b5b9d43db336bf0c0660de5804a75ceefacb38dce5c703922ea76dc847593d84
diff --git a/net-voip/jami-daemon/jami-daemon-0_pre20230113.ebuild b/net-voip/jami-daemon/jami-daemon-0_pre20230113.ebuild
new file mode 100644
index 0000000..1d75a7e
--- /dev/null
+++ b/net-voip/jami-daemon/jami-daemon-0_pre20230113.ebuild
@@ -0,0 +1,90 @@
+# Copyright 2022-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit meson
+
+COMMIT="3062351d377cc055a4bcc697ec4501a22d534229"
+PJCOMMIT="eae25732568e600d248aa8c226271ff6b81df170"
+DESCRIPTION="Daemon for the Jami VoIP software phone"
+HOMEPAGE="https://jami.net"
+SRC_URI="https://git.jami.net/savoirfairelinux/${PN}/-/archive/${COMMIT}.tar.bz2 -> ${P}.tar.bz2
+	https://github.com/savoirfairelinux/pjproject/archive/${PJCOMMIT}.tar.gz -> pjproject-${PJCOMMIT}.tar.gz
+"
+S="${WORKDIR}/${PN}-${COMMIT}"
+
+LICENSE="GPL-3+"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE="alsa hwaccel jack nameservice natpmp plugins portaudio pulseaudio speex test trace upnp video webrtc"
+REQUIRED_USE="hwaccel? ( video )"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	dev-cpp/yaml-cpp
+	dev-libs/dbus-c++
+	dev-libs/Ice
+	dev-libs/libfmt
+	dev-libs/jsoncpp
+	dev-libs/libgit2
+	dev-libs/libsecp256k1
+	dev-libs/nettle
+	dev-libs/opendht
+	media-libs/speex
+	media-libs/speexdsp
+	media-video/ffmpeg:0/57.59.59
+	net-libs/gnutls
+	net-libs/pjproject
+	sys-libs/zlib
+	alsa? ( media-libs/alsa-lib )
+	jack? ( media-sound/jack2 )
+	nameservice? ( dev-libs/openssl:= )
+	natpmp? ( net-libs/libnatpmp )
+	plugins? ( app-arch/libarchive )
+	portaudio? ( media-libs/portaudio )
+	pulseaudio? ( media-libs/libpulse )
+	upnp? ( net-libs/libupnp )
+	test? ( dev-util/cppunit )
+	trace? ( dev-util/lttng-ust )
+	video? ( virtual/libudev )
+	webrtc? ( media-libs/webrtc-audio-processing )
+"
+DEPEND="${RDEPEND}"
+
+src_prepare() {
+	default
+	cp "${DISTDIR}/pjproject-${PJCOMMIT}.tar.gz" "${S}/contrib/tarballs" || die
+	mkdir "${S}/contrib/native"
+}
+
+src_configure() {
+	cd "${S}/contrib/native" || die
+	../bootstrap --disable-downloads --disable-all --enable-pjproject || die
+	emake DEPS_pjproject=
+
+	emesonargs=(
+		$(meson_feature alsa)
+		$(meson_feature jack)
+		$(meson_feature natpmp)
+		$(meson_feature portaudio)
+		$(meson_feature pulseaudio)
+		$(meson_feature speex speex_ap)
+		$(meson_feature upnp)
+		$(meson_feature webrtc webrtc_ap)
+		$(meson_use hwaccel hw_acceleration)
+		$(meson_use plugins)
+		$(meson_use test tests)
+		$(meson_use trace tracepoints)
+		$(meson_use video)
+	)
+
+	export PKG_CONFIG_PATH="${S}/contrib/$(cc -dumpmachine)/lib/pkgconfig"
+	meson_src_configure
+}
+
+src_compile() {
+	export PATH="${PATH}:${S}/contrib/$(cc -dumpmachine)/bin"
+	export PKG_CONFIG_PATH="${S}/contrib/$(cc -dumpmachine)/lib/pkgconfig"
+	meson_src_compile
+}
diff --git a/net-voip/jami-daemon/metadata.xml b/net-voip/jami-daemon/metadata.xml
new file mode 100644
index 0000000..2609d35
--- /dev/null
+++ b/net-voip/jami-daemon/metadata.xml
@@ -0,0 +1,22 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "https://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<maintainer type="person">
+		<email>julien@jroy.ca</email>
+		<name>Julien Roy</name>
+	</maintainer>
+	<upstream>
+		<doc>https://docs.jami.net/user/faq.html</doc>
+		<bugs-to>https://git.jami.net/savoirfairelinux/jami-daemon/-/issues</bugs-to>
+		<remote-id  type="github">savoirfairelinux/pjproject</remote-id>
+	</upstream>
+	<use>
+		<flag name="hwaccel">Enable hardware acceleration</flag>
+		<flag name="nameservice">Enable Name Service</flag>
+		<flag name="natpmp">Enable support for NAT-PMP</flag>
+		<flag name="plugins">Enable support for plugins</flag>
+		<flag name="trace">Enable tracepoints</flag>
+		<flag name="video">Enable video support</flag>
+		<flag name="webrtc">Enable support for WebRTC audio processing</flag>
+	</use>
+</pkgmetadata>