1 files changed, 74 insertions, 0 deletions
diff --git a/net-voip/jami-client-qt/jami-client-qt-0_pre20230260.ebuild b/net-voip/jami-client-qt/jami-client-qt-0_pre20230260.ebuild
new file mode 100644
index 0000000..10dbb7b
--- /dev/null
+++ b/net-voip/jami-client-qt/jami-client-qt-0_pre20230260.ebuild
@@ -0,0 +1,74 @@
+# Copyright 2022-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake xdg-utils
+
+COMMIT="2853d185b83fe49785169fd408cf1649e437b8e5"
+SFPMCOMMIT="a2a0c72e4db38e1c5478bd3e0f67ff99fae11f00"
+DESCRIPTION="Share, freely and privately."
+HOMEPAGE="https://jami.net"
+SRC_URI="https://git.jami.net/savoirfairelinux/${PN}/-/archive/${COMMIT}.tar.bz2 -> ${P}.tar.bz2
+	https://github.com/atraczyk/SortFilterProxyModel/archive/${SFPMCOMMIT}.tar.gz -> sfpm.tar.gz
+"
+S="${WORKDIR}/${PN}-${COMMIT}"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE="doc +notify +plugins +video webengine"
+
+RDEPEND="
+	dev-qt/qtbase:6
+	dev-qt/qtdeclarative:6
+	dev-qt/qtmultimedia:6[gstreamer]
+	dev-qt/qtnetworkauth:6
+	dev-qt/qtpositioning:6
+	dev-qt/qtsvg:6
+	dev-qt/qttools:6[linguist]
+	dev-qt/qt5compat:6
+	media-gfx/qrencode
+	net-voip/jami-daemon[plugins?,video?]
+	x11-libs/gdk-pixbuf
+	x11-libs/libxcb
+	doc? ( app-doc/doxygen )
+	notify? (
+		x11-libs/libnotify
+		dev-libs/libappindicator
+	)
+	webengine? (
+		dev-qt/qtwebengine:6[widgets]
+		dev-qt/qtwebchannel:6
+	)
+"
+DEPEND="${RDEPEND}"
+
+src_unpack() {
+	default
+	rmdir "${S}/3rdparty/SortFilterProxyModel"
+	mv "${WORKDIR}/SortFilterProxyModel-${SFPMCOMMIT}" "${S}/3rdparty/SortFilterProxyModel" || die
+}
+
+src_configure() {
+	local mycmakeargs=(
+		"-DENABLE_LIBWRAP=ON"
+		"-DENABLE_PLUGIN=$(usex plugins true false)"
+		"-DENABLE_VIDEO=$(usex video true false)"
+		"-DWITH_WEBENGINE=$(usex webengine)"
+	)
+
+	cmake_src_configure
+}
+
+pkg_postinst() {
+	xdg_mimeinfo_database_update
+	xdg_desktop_database_update
+	xdg_icon_cache_update
+}
+
+pkg_postrm() {
+	xdg_mimeinfo_database_update
+	xdg_desktop_database_update
+	xdg_icon_cache_update
+}