1 files changed, 63 insertions, 0 deletions
diff --git a/dev-python/zope-publisher/zope-publisher-6.1.0.ebuild b/dev-python/zope-publisher/zope-publisher-6.1.0.ebuild
new file mode 100644
index 0000000..6470fad
--- /dev/null
+++ b/dev-python/zope-publisher/zope-publisher-6.1.0.ebuild
@@ -0,0 +1,63 @@
+# Copyright 2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{9..11} )
+
+inherit distutils-r1
+
+DESCRIPTION="Map requests from HTTP/WebDAV clients, web browsers, XML-RPC and FTP clients"
+HOMEPAGE="https://github.com/zopefoundation/zope.publisher"
+SRC_URI="https://github.com/zopefoundation/zope.publisher/archive/${PV}.tar.gz -> ${P}.gh.tar.gz"
+S="${WORKDIR}/${PN/-/\.}-${PV}"
+
+LICENSE="ZPL"
+SLOT="0"
+KEYWORDS="~amd64"
+
+RDEPEND="
+	dev-python/six[${PYTHON_USEDEP}]
+	dev-python/multipart[${PYTHON_USEDEP}]
+	dev-python/zope-browser[${PYTHON_USEDEP}]
+	dev-python/zope-component[${PYTHON_USEDEP}]
+	dev-python/zope-configuration[${PYTHON_USEDEP}]
+	dev-python/zope-contenttype[${PYTHON_USEDEP}]
+	dev-python/zope-event[${PYTHON_USEDEP}]
+	dev-python/zope-exceptions[${PYTHON_USEDEP}]
+	dev-python/zope-i18n[${PYTHON_USEDEP}]
+	dev-python/zope-interface[${PYTHON_USEDEP}]
+	dev-python/zope-location[${PYTHON_USEDEP}]
+	dev-python/zope-proxy[${PYTHON_USEDEP}]
+	dev-python/zope-security[${PYTHON_USEDEP}]
+	doc? (
+		dev-python/repoze-sphinx-autointerface[${PYTHON_USEDEP}]
+		dev-python/sphinx_rtd_theme[${PYTHON_USEDEP}]
+	)
+	test? (
+		dev-python/zope-testing[${PYTHON_USEDEP}]
+		dev-python/zope-testrunner[${PYTHON_USEDEP}]
+	)
+"
+DEPEND="${RDEPEND}"
+
+distutils_enable_sphinx docs
+distutils_enable_tests unittest
+
+src_prepare() {
+	# strip rdep specific to namespaces
+	sed -i -e "/'setuptools'/d" setup.py || die
+	distutils-r1_src_prepare
+}
+
+python_compile() {
+	distutils-r1_python_compile
+	find "${BUILD_DIR}" -name '*.pth' -delete || die
+}
+
+python_test() {
+	cd "${BUILD_DIR}/install$(python_get_sitedir)" || die
+	distutils_write_namespace zope
+	eunittest
+}