net-voip/jami-daemon: add 0_pre20230208, drop 0_pre20230113

Signed-off-by: Julien Roy <julien@jroy.ca>

1 files changed, 93 insertions, 0 deletions

diff --git a/net-voip/jami-daemon/jami-daemon-0_pre20230208.ebuild b/net-voip/jami-daemon/jami-daemon-0_pre20230208.ebuild
new file mode 100644
index 0000000..73a3e72
--- /dev/null
+++ b/net-voip/jami-daemon/jami-daemon-0_pre20230208.ebuild
@@ -0,0 +1,93 @@
+# Copyright 2022-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit meson
+
+COMMIT="2217de2860d39736c288274796a6dc2c4d32589d"
+PJCOMMIT="3b78ef1c48732d238ba284cdccb04dc6de79c54f"
+DESCRIPTION="Daemon for the Jami VoIP software phone"
+HOMEPAGE="https://jami.net"
+SRC_URI="https://git.jami.net/savoirfairelinux/${PN}/-/archive/${COMMIT}.tar.bz2 -> ${P}.tar.bz2
+	https://github.com/savoirfairelinux/pjproject/archive/${PJCOMMIT}.tar.gz -> pjproject-${PJCOMMIT}.tar.gz
+"
+S="${WORKDIR}/${PN}-${COMMIT}"
+
+LICENSE="GPL-3+"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE="alsa debug hwaccel jack natpmp plugins portaudio pulseaudio test trace upnp +video +webrtc"
+# IUSE+="speex" # Compilation fails with speex enabled
+REQUIRED_USE="hwaccel? ( video )"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	dev-cpp/yaml-cpp
+	dev-libs/dbus-c++
+	dev-libs/Ice
+	dev-libs/libfmt
+	dev-libs/jsoncpp
+	dev-libs/libgit2
+	dev-libs/libsecp256k1
+	dev-libs/nettle
+	dev-libs/opendht[api]
+	dev-libs/openssl:=
+	media-libs/speex
+	media-libs/speexdsp
+	media-video/ffmpeg:0/57.59.59
+	net-libs/gnutls
+	net-libs/pjproject
+	sys-libs/zlib
+	alsa? ( media-libs/alsa-lib )
+	debug? ( sys-devel/gdb )
+	jack? ( media-sound/jack2 )
+	natpmp? ( net-libs/libnatpmp )
+	plugins? ( app-arch/libarchive )
+	portaudio? ( media-libs/portaudio )
+	pulseaudio? ( media-libs/libpulse )
+	upnp? ( net-libs/libupnp )
+	test? ( dev-util/cppunit )
+	trace? ( dev-util/lttng-ust )
+	video? ( virtual/libudev )
+	webrtc? ( media-libs/webrtc-audio-processing )
+"
+DEPEND="${RDEPEND}"
+
+src_prepare() {
+	default
+	cp "${DISTDIR}/pjproject-${PJCOMMIT}.tar.gz" "${S}/contrib/tarballs" || die
+	mkdir "${S}/contrib/native"
+}
+
+src_configure() {
+	cd "${S}/contrib/native" || die
+	../bootstrap --disable-downloads --disable-all --enable-pjproject || die
+	emake DEPS_pjproject=
+
+	emesonargs=(
+		$(meson_feature alsa)
+		$(meson_feature jack)
+		$(meson_feature natpmp)
+		$(meson_feature portaudio)
+		$(meson_feature pulseaudio)
+		# $(meson_feature speex speex_ap)
+		$(meson_feature upnp)
+		$(meson_feature webrtc webrtc_ap)
+		$(meson_use debug)
+		$(meson_use hwaccel hw_acceleration)
+		$(meson_use plugins)
+		$(meson_use test tests)
+		$(meson_use trace tracepoints)
+		$(meson_use video)
+	)
+
+	export PKG_CONFIG_PATH="${S}/contrib/$(cc -dumpmachine)/lib/pkgconfig"
+	meson_src_configure
+}
+
+src_compile() {
+	export PATH="${PATH}:${S}/contrib/$(cc -dumpmachine)/bin"
+	export PKG_CONFIG_PATH="${S}/contrib/$(cc -dumpmachine)/lib/pkgconfig"
+	meson_src_compile
+}