net-im/mautrix-telegram: add 0.12.2_p20230118, drop 0.12.2

Signed-off-by: Julien Roy <julien@jroy.ca>

1 files changed, 77 insertions, 0 deletions

diff --git a/net-im/mautrix-telegram/mautrix-telegram-0.12.2_p20230118.ebuild b/net-im/mautrix-telegram/mautrix-telegram-0.12.2_p20230118.ebuild
new file mode 100644
index 0000000..66ac561
--- /dev/null
+++ b/net-im/mautrix-telegram/mautrix-telegram-0.12.2_p20230118.ebuild
@@ -0,0 +1,77 @@
+# Copyright 2022-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{9..10} )
+
+inherit distutils-r1 optfeature systemd
+
+COMMIT="e655e0a8826eb66e3f133cfe6ab912d275a55715"
+DESCRIPTION="A Matrix-Telegram Messenger puppeting bridge "
+HOMEPAGE="https://github.com/mautrix/telegram/"
+SRC_URI="https://github.com/mautrix/telegram/archive/${COMMIT}.tar.gz -> ${P}.gh.tar.gz"
+S="${WORKDIR}/telegram-${COMMIT}"
+
+LICENSE="AGPL-3"
+SLOT="0"
+KEYWORDS="~amd64"
+
+RDEPEND="
+	acct-user/${PN}
+	app-arch/brotli[python]
+	dev-python/aiohttp[${PYTHON_USEDEP}]
+	dev-python/aiodns[${PYTHON_USEDEP}]
+	dev-python/asyncpg[${PYTHON_USEDEP}]
+	dev-python/commonmark[${PYTHON_USEDEP}]
+	dev-python/cryptg[${PYTHON_USEDEP}]
+	dev-python/mako[${PYTHON_USEDEP}]
+	dev-python/mautrix[${PYTHON_USEDEP}]
+	dev-python/olm[${PYTHON_USEDEP}]
+	dev-python/phonenumbers[${PYTHON_USEDEP}]
+	dev-python/pycryptodome[${PYTHON_USEDEP}]
+	dev-python/python-magic[${PYTHON_USEDEP}]
+	dev-python/qrcode[${PYTHON_USEDEP}]
+	dev-python/ruamel-yaml[${PYTHON_USEDEP}]
+	~dev-python/tulir-telethon-1.27.0_alpha1[${PYTHON_USEDEP}]
+	dev-python/unpaddedbase64[${PYTHON_USEDEP}]
+	dev-python/yarl[${PYTHON_USEDEP}]
+"
+DEPEND="${RDEPEND}"
+
+src_install() {
+	distutils-r1_src_install
+
+	keepdir /var/log/mautrix
+	fowners root:mautrix /var/log/mautrix
+	fperms 770 /var/log/mautrix
+	sed -i -e "s/\.\/${PN}.log/\/var\/log\/mautrix\/${PN}.log/" "${ED}/usr/example-config.yaml" || die
+
+	insinto "/etc/mautrix"
+	newins "${ED}/usr/example-config.yaml" "${PN/-/_}.yaml"
+	rm "${ED}/usr/example-config.yaml" || die
+
+	newinitd "${FILESDIR}/${PN}.initd" "${PN}"
+	systemd_newunit "${FILESDIR}/${PN}.unit" "${PN}.service"
+
+	fowners -R root:mautrix /etc/mautrix
+	fperms -R 770 /etc/mautrix
+}
+
+pkg_postinst() {
+	einfo
+	elog "Before you can use ${PN}, you must configure it correctly."
+	elog "The configuration file is located at \"/etc/mautrix/${PN/-/_}.yaml\""
+	elog "Next, you must generate a registration file using the following command"
+	elog "sudo -u ${PN} /usr/bin/python -m ${PN/-/_} -c /etc/mautrix/${PN}.yaml g"
+	elog "Next, you must register you registration.yaml file with your homeserver"
+	elog "Then you must launch ${PN} by specifying the registration file"
+	elog "sudo -u ${PN} /usr/bin/python -m ${PN/-/_} -r registration.yaml"
+	elog "After this you can register the bridge with your homeserver"
+	elog "Finally, you can start the ${PN} daemon"
+	einfo
+
+	optfeature "Prometheus statistics" dev-python/prometheus_client
+	optfeature "Sqlite backend" dev-python/aiosqlite
+}