dev-python/zope-copy: new package, add 4.3

Signed-off-by: Julien Roy <julien@jroy.ca>

1 files changed, 49 insertions, 0 deletions

diff --git a/dev-python/zope-copy/zope-copy-4.3.ebuild b/dev-python/zope-copy/zope-copy-4.3.ebuild
new file mode 100644
index 0000000..e42cfee
--- /dev/null
+++ b/dev-python/zope-copy/zope-copy-4.3.ebuild
@@ -0,0 +1,49 @@
+# Copyright 2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{9..11} )
+
+inherit distutils-r1
+
+DESCRIPTION="pluggable mechanism for copying persistent objects"
+HOMEPAGE="https://github.com/zopefoundation/zope.copy"
+SRC_URI="https://github.com/zopefoundation/zope.copy/archive/${PV}.tar.gz -> ${P}.gh.tar.gz"
+S="${WORKDIR}/${PN/-/\.}-${PV}"
+
+LICENSE="ZPL"
+SLOT="0"
+KEYWORDS="~amd64"
+
+RDEPEND="
+	dev-python/zope-interface[${PYTHON_USEDEP}]
+	doc? ( dev-python/repoze-sphinx-autointerface[${PYTHON_USEDEP}] )
+	test? (
+		dev-python/zope-component[${PYTHON_USEDEP}]
+		dev-python/zope-location[${PYTHON_USEDEP}]
+		dev-python/zope-testing[${PYTHON_USEDEP}]
+		dev-python/zope-testrunner[${PYTHON_USEDEP}]
+	)
+"
+DEPEND="${RDEPEND}"
+
+distutils_enable_sphinx docs
+distutils_enable_tests unittest
+
+src_prepare() {
+	# strip rdep specific to namespaces
+	sed -i -e "/'setuptools'/d" setup.py || die
+	distutils-r1_src_prepare
+}
+
+python_compile() {
+	distutils-r1_python_compile
+	find "${BUILD_DIR}" -name '*.pth' -delete || die
+}
+
+src_test() {
+	cd "${S}/src/zope/copy" || die
+	distutils-r1_src_test
+}