# Copyright 2023-2024 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=8

PYTHON_COMPAT=( python3_{10..13} )
DISTUTILS_USE_PEP517=setuptools

inherit databases distutils-r1

DESCRIPTION="Extensions to Django for use with MySQL/MariaDB"
HOMEPAGE="
	https://pypi.org/project/django-mysql
	https://github.com/adamchainz/django-mysql
"
# PyPI doesn't have tests
SRC_URI="https://github.com/adamchainz/django-mysql/archive/${PV}.tar.gz -> ${P}.gh.tar.gz"

LICENSE="BSD"
SLOT="0"
KEYWORDS="~amd64"
# MySQL test issue
RESTRICT="test"

RDEPEND="
	>=dev-python/django-3.2[${PYTHON_USEDEP}]
	dev-python/mysqlclient[${PYTHON_USEDEP}]
	dev-python/parameterized[${PYTHON_USEDEP}]
	dev-python/typing-extensions[${PYTHON_USEDEP}]

	test? (
		dev-python/pytest-django[${PYTHON_USEDEP}]
	)
"
DEPEND="${RDEPEND}"

distutils_enable_tests pytest

python_test() {
	export DB_HOST="127.0.0.1"
	export DB_PORT="33060"
	export DB_USER="admin"

	epytest \
		`# These tests depend on a deprecated library` \
		--ignore tests/testapp/test_dynamicfield.py \
		--ignore tests/testapp/test_functions.py
}

src_test() {
	emysql --start 33060
	distutils-r1_src_test
	emysql --stop
}