# Copyright 2023-2024 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=8

PYTHON_COMPAT=( python3_{10..13} pypy3 )

inherit python-single-r1 systemd

DESCRIPTION="Utility for compiling packages on remote hosts using Portage"
HOMEPAGE="https://gitlab.com/doasu/puppy"

if [[ ${PV} == 9999 ]]; then
	EGIT_REPO_URI="https://gitlab.com/doasu/${PN}.git"
	EGIT_BRANCH="unittest"
	inherit git-r3
else
	SRC_URI="https://gitlab.com/doasu/${PN}/-/archive/${PV}/${P}.tar.bz2"
	KEYWORDS="~amd64"
fi

LICENSE="AGPL-3"
SLOT="0"
IUSE="+client +server test"
REQUIRED_USE="
	|| ( client server )
	${PYTHON_REQUIRED_USE}
"
RESTRICT="!test? ( test )"

RDEPEND="
	sys-apps/portage
	${PYTHON_DEPS}

	test? ( dev-python/unittest-or-fail[${PYTHON_SINGLE_USEDEP}] )
"
DEPEND="${RDEPEND}"

src_test() {
	eunittest
}

src_install() {
	python_domodule _common.py
	python_domodule _request.py

	if use server; then
		python_doscript puppyd

		newconfd "${S}/packaging/puppyd.conf.d" puppyd
		newinitd "${S}/packaging/puppyd.init.d" puppyd

		systemd_newunit packaging/puppyd.service puppyd.service
	fi

	if use client; then
		python_doscript pup.py
	fi
}