From edaddb1ad580c67dd7550e8dedc4d64be0e74316 Mon Sep 17 00:00:00 2001
From: Julien Roy <julien@jroy.ca>
Date: Wed, 11 Jan 2023 09:11:01 -0500
Subject: gui-apps/waybar: new package, add 0.9.13, 0.9.16, 0.9.17, 9999

Signed-off-by: Julien Roy <julien@jroy.ca>
---
 gui-apps/waybar/waybar-0.9.17.ebuild | 72 ++++++++++++++++++++++++++++++++++++
 1 file changed, 72 insertions(+)
 create mode 100644 gui-apps/waybar/waybar-0.9.17.ebuild

(limited to 'gui-apps/waybar/waybar-0.9.17.ebuild')

diff --git a/gui-apps/waybar/waybar-0.9.17.ebuild b/gui-apps/waybar/waybar-0.9.17.ebuild
new file mode 100644
index 0000000..90a862c
--- /dev/null
+++ b/gui-apps/waybar/waybar-0.9.17.ebuild
@@ -0,0 +1,72 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit meson
+
+DESCRIPTION="Highly customizable Wayland bar for Sway and Wlroots based compositors"
+HOMEPAGE="https://github.com/Alexays/Waybar"
+
+if [[ ${PV} == 9999 ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/Alexays/${PN^}.git"
+else
+	SRC_URI="https://github.com/Alexays/${PN^}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64"
+fi
+S="${WORKDIR}/${PN^}-${PV}"
+
+LICENSE="MIT"
+SLOT="0"
+IUSE="experimental mpd network +popups pulseaudio sndio tray +udev wifi"
+
+BDEPEND="
+	>=app-text/scdoc-1.9.2
+	dev-util/gdbus-codegen
+	virtual/pkgconfig
+"
+DEPEND="
+	dev-cpp/cairomm:0
+	dev-cpp/glibmm:2
+	dev-cpp/gtkmm:3.0
+	dev-libs/glib:2
+	dev-libs/jsoncpp:=
+	dev-libs/libinput:=
+	dev-libs/libsigc++:2
+	>=dev-libs/libfmt-7.0.0:=
+	>=dev-libs/spdlog-1.8.5:=
+	dev-libs/date:=
+	dev-libs/wayland
+	dev-libs/wayland-protocols
+	gui-libs/wlroots:=
+	x11-libs/gtk+:3[wayland]
+	x11-libs/libxkbcommon
+	mpd? ( media-libs/libmpdclient )
+	network? ( dev-libs/libnl:3 )
+	popups? ( gui-libs/gtk-layer-shell )
+	pulseaudio? ( media-sound/pulseaudio )
+	sndio? ( media-sound/sndio:= )
+	tray? (
+		dev-libs/libdbusmenu[gtk3]
+		dev-libs/libappindicator
+	)
+	udev? ( virtual/libudev:= )
+	wifi? ( || ( sys-apps/util-linux net-wireless/rfkill ) )
+"
+RDEPEND="${DEPEND}"
+
+src_configure() {
+	local emesonargs=(
+		$(meson_feature mpd)
+		$(meson_feature network libnl)
+		$(meson_feature popups gtk-layer-shell)
+		$(meson_feature pulseaudio)
+		$(meson_feature sndio)
+		$(meson_feature tray dbusmenu-gtk)
+		$(meson_feature udev libudev)
+		$(meson_feature wifi rfkill)
+		$(meson_use experimental)
+	)
+	meson_src_configure
+}
-- 
cgit v1.2.3