From ec479a42e6dc2d7137f54063fe8596be1d8dbdaf Mon Sep 17 00:00:00 2001
From: Julien Roy <julien@jroy.ca>
Date: Sat, 4 Feb 2023 20:55:11 -0500
Subject: dev-python/zope-untrustedpython: new package, add 5.0

Signed-off-by: Julien Roy <julien@jroy.ca>
---
 .../zope-untrustedpython-5.0.ebuild                | 43 ++++++++++++++++++++++
 1 file changed, 43 insertions(+)
 create mode 100644 dev-python/zope-untrustedpython/zope-untrustedpython-5.0.ebuild

(limited to 'dev-python/zope-untrustedpython/zope-untrustedpython-5.0.ebuild')

diff --git a/dev-python/zope-untrustedpython/zope-untrustedpython-5.0.ebuild b/dev-python/zope-untrustedpython/zope-untrustedpython-5.0.ebuild
new file mode 100644
index 0000000..37e79d2
--- /dev/null
+++ b/dev-python/zope-untrustedpython/zope-untrustedpython-5.0.ebuild
@@ -0,0 +1,43 @@
+# Copyright 2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{9..11} )
+
+inherit distutils-r1
+
+DESCRIPTION="Sandboxed environment for untrusted code / templates"
+HOMEPAGE="https://github.com/zopefoundation/zope.untrustedpython"
+SRC_URI="https://github.com/zopefoundation/zope.untrustedpython/archive/${PV}.tar.gz -> ${P}.gh.tar.gz"
+S="${WORKDIR}/${PN/-/\.}-${PV}"
+
+LICENSE="ZPL"
+SLOT="0"
+KEYWORDS="~amd64"
+
+RDEPEND="
+	dev-python/restrictedpython[${PYTHON_USEDEP}]
+	dev-python/zope-security[${PYTHON_USEDEP}]
+"
+DEPEND="${RDEPEND}"
+
+distutils_enable_sphinx docs
+distutils_enable_tests unittest
+
+src_prepare() {
+	# strip rdep specific to namespaces
+	sed -i -e "/'setuptools'/d" setup.py || die
+	distutils-r1_src_prepare
+}
+
+python_compile() {
+	distutils-r1_python_compile
+	find "${BUILD_DIR}" -name '*.pth' -delete || die
+}
+
+src_test() {
+	cd "${S}/src/zope/untrustedpython" || die
+	distutils-r1_src_test
+}
-- 
cgit v1.2.3