From 21aeb0503594581beae5651410ef266cfd67b282 Mon Sep 17 00:00:00 2001
From: Julien Roy <julien@jroy.ca>
Date: Sun, 15 Jan 2023 15:42:18 -0500
Subject: dev-libs/restinio: new package, add 0.6.17

Signed-off-by: Julien Roy <julien@jroy.ca>
---
 dev-libs/restinio/Manifest               |  1 +
 dev-libs/restinio/metadata.xml           | 15 ++++++++++
 dev-libs/restinio/restinio-0.6.17.ebuild | 51 ++++++++++++++++++++++++++++++++
 3 files changed, 67 insertions(+)
 create mode 100644 dev-libs/restinio/Manifest
 create mode 100644 dev-libs/restinio/metadata.xml
 create mode 100644 dev-libs/restinio/restinio-0.6.17.ebuild

diff --git a/dev-libs/restinio/Manifest b/dev-libs/restinio/Manifest
new file mode 100644
index 0000000..9199c79
--- /dev/null
+++ b/dev-libs/restinio/Manifest
@@ -0,0 +1 @@
+DIST restinio-0.6.17.gh.tar.gz 670089 BLAKE2B e80f83ac4b2116f2d0acaa0022bc34aa7f772cd1f96b296229b075e1eab13c388bdeb50eb56f8e6d197a709685d2609813dc0b44bb9c00b2396c267b8aa38ebb SHA512 a324246dac1a708ad94ca9beb5d34c761e7393463b6ca5ec7606b82a3b6fe0e79ebf401dfadb9458d6a8cb5c3c75d22f10ff993ae9823a5a1da2d87b4a31483e
diff --git a/dev-libs/restinio/metadata.xml b/dev-libs/restinio/metadata.xml
new file mode 100644
index 0000000..625fa20
--- /dev/null
+++ b/dev-libs/restinio/metadata.xml
@@ -0,0 +1,15 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "https://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<maintainer type="person">
+		<email>julien@jroy.ca</email>
+		<name>Julien Roy</name>
+	</maintainer>
+	<longdescription>RESTinio is a header-only C++14 library that gives you an embedded HTTP/Websocket server. It is based on standalone version of ASIO and targeted primarily for asynchronous processing of HTTP-requests. </longdescription>
+	<upstream>
+		<changelog>https://github.com/Stiffstream/restinio/releases</changelog>
+		<doc>https://stiffstream.com/en/docs/restinio/0.6/</doc>
+		<bugs-to>https://github.com/Stiffstream/restinio/issues</bugs-to>
+		<remote-id type="github">Stiffstream/restinio</remote-id>
+	</upstream>
+</pkgmetadata>
diff --git a/dev-libs/restinio/restinio-0.6.17.ebuild b/dev-libs/restinio/restinio-0.6.17.ebuild
new file mode 100644
index 0000000..93a0286
--- /dev/null
+++ b/dev-libs/restinio/restinio-0.6.17.ebuild
@@ -0,0 +1,51 @@
+# Copyright 2022-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake
+
+DESCRIPTION="Asynchronous HTTP/WebSocket server C++14 library"
+HOMEPAGE="https://github.com/Stiffstream/restinio"
+SRC_URI="https://github.com/Stiffstream/${PN}/archive/v.${PV}.tar.gz -> ${P}.gh.tar.gz"
+S="${WORKDIR}/${PN}-v.${PV}/dev"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+# RESTinio is not compatible with catch2-v3
+# https://github.com/Stiffstream/restinio/issues/158
+RDEPEND="
+	dev-cpp/asio
+	<=dev-cpp/catch-3
+	dev-libs/boost
+	dev-libs/libfmt
+	dev-libs/libpcre
+	dev-libs/libpcre2
+	dev-libs/openssl
+	net-libs/http-parser
+	sys-libs/zlib
+"
+DEPEND="${RDEPEND}"
+
+src_configure() {
+	local mycmakeargs=(
+		"-DRESTINIO_BENCH=OFF"
+		"-DRESTINIO_FIND_DEPS=ON"
+		"-DRESTINIO_SAMPLE=OFF"
+		"-DRESTINIO_TEST=$(usex test ON OFF)"
+		"-DRESTINIO_USE_EXTERNAL_HTTP_PARSER=ON"
+		"-DRESTINIO_USE_EXTERNAL_SOBJECTIZER=ON"
+	)
+	cmake_src_configure
+}
+
+src_test() {
+	# Some tests open a socket on port 8085
+	# Running these tests in parallel will cause
+	# failures since the port is already in use
+	cmake_src_test -j 1
+}
-- 
cgit v1.2.3